Draw (método BitmapData.draw)

public draw(source: Object, [matrix: Matrix], [colorTransform: ColorTransform], [blendMode: Object], [clipRect: Rectangle], [smooth: Boolean]) : Void


Dibuja una imagen de origen o un clip de película en una imagen de destino, mediante el procesador de vectores de Flash Player. Se puede especificar una matriz de transformación, un objeto ColorTransform, una configuración de modo de mezcla y un objeto Rectangle de destino para controlar la representación. También puede especificar si el mapa de bits se debe suavizar cuando se escala. Eso sólo funciona si el objeto de origen es un objeto BitmapData.
Este método corresponde directamente a cómo se dibujan los objetos utilizando el procesador de vectores estándar para objetos en la interfaz de la herramienta de edición.

Un objeto MovieClip de origen no utiliza ninguna de sus transformaciones en el escenario para esta llamada. Se procesa tal como se encuentra en la biblioteca o el archivo, sin transformación de matriz, transformación de color ni modo de mezcla. Si desea dibujar un clip de película empleando sus propias propiedades de transformación, puede utilizar su objeto Transform para transferir las distintas propiedades de transformación.



Algunos Parámetros importantes son :


source: Object - El objeto que se va a dibujar.

matrix: Matrix [opcional] - Un objeto Matrix empleado para escalar, rotar o convertir las coordenadas del mapa de bits. Si no se proporciona ningún objeto, no se transformará la imagen de mapa de bits. Defina ese parámetro como una matriz de identidad, creada mediante el constructor new Matrix() predeterminado, si tiene que pasar este parámetro pero no desea transformar la imagen.


colorTransform: ColorTransform [opcional] - Un objeto ColorTransform empleado para ajustar los valores de color del mapa de bits. Si no se proporciona ningún objeto, no se transformarán los colores de la imagen de mapa de bits. Defina ese parámetro a un objeto ColorTransform creada mediante el constructor new ColorTransform() predeterminado, si tiene que pasar este parámetro pero no desea transformar la imagen.


blendMode: Object [opcional] - Una configuración de modo de mezcla para la transformación. Este parámetro puede ser un entero (de 1 a 14) o una cadena (por ejemplo, "normal" o "darken"). Para obtener una lista de valores blendMode válidos, consulte la propiedad blendMode de la clase MovieClip.
clipRect: Rectangle [opcional] - Un objeto Rectangle. Si no proporciona este valor, no se produce recorte.


smooth: Boolean [opcional] - Un valor booleano que determina si un objeto BitmapData se suaviza al cambiar la escala o al girarse, debido al cambio de escala o rotación del parámetro matrix. El valor predeterminado es false. El parámetro smoothing se aplica solamente si el parámetro source es un objeto BitmapData. Con smoothing establecido como false, la imagen BitmapData escalada o girada puede aparecer pixelada o con bordes dentados. Por ejemplo, las dos imágenes siguientes utilizan el mismo objeto BitmapData para el parámetro source, pero el parámetro smoothing está establecido en true a la izquierda y como false a la derecha:

Nota.-Dibujar un mapa de bits con smoothing establecido como true lleva más tiempo que hacerlo con smoothing establecido como false.


En este ejemplo siguiente se muestra cómo dibujar una instancia MovieClip de origen en un objeto BitmapData.

import flash.display.BitmapData;
import flash.geom.Rectangle;
import flash.geom.Matrix;
import flash.geom.ColorTransform;

var myBitmapData:BitmapData = new BitmapData(100, 80, false, 0x00CCCCCC);

var mc_1:MovieClip = this.createEmptyMovieClip("mc", this.getNextHighestDepth());
mc_1.attachBitmap(myBitmapData, this.getNextHighestDepth());

var mc_2:MovieClip = createRectangle(50, 40, 0xFF0000);
mc_2._x = 101;

var myMatrix:Matrix = new Matrix();
myMatrix.rotate(Math.PI/2);

var translateMatrix:Matrix = new Matrix();
translateMatrix.translate(70, 15);

myMatrix.concat(translateMatrix);

var myColorTransform:ColorTransform = new ColorTransform(0, 0, 1, 1, 0, 0, 255, 0);
var blendMode:String = "normal";

var myRectangle:Rectangle = new Rectangle(0, 0, 100, 80);
var smooth:Boolean = true;

mc_1.onPress = function() {
myBitmapData.draw(mc_2, myMatrix, myColorTransform, blendMode, myRectangle, smooth);
}

function createRectangle(width:Number, height:Number, color:Number):MovieClip {
var depth:Number = this.getNextHighestDepth();
var mc:MovieClip = this.createEmptyMovieClip("mc_" + depth, depth);
mc.beginFill(color);
mc.lineTo(0, height);
mc.lineTo(width, height);
mc.lineTo(width, 0);
mc.lineTo(0, 0);
return mc;
}